Decrypt this:

[na_th_an]

This challenge isn't challenging no more. Here is my original proggie:

Code:

DECLARE FUNCTION decript$ (a$)
DECLARE FUNCTION encript$ (a$)
a$ = "HELLO WORLD"
PRINT a$
b$ = encript$(a$)
PRINT b$
c$ = decript$(b$)
PRINT c$

FUNCTION decript$ (a$)
   c% = VAL(a$): res$ = CHR$(c%)
   o$ = RIGHT$(a$, LEN(a$) - LEN(LTRIM$(STR$(VAL(a$)))))
   WHILE o$ <> ""
      m$ = LEFT$(o$, 1)
      o$ = RIGHT$(o$, LEN(o$) - 1)
      IF m$ = "<" THEN c% = c% - VAL(o$) ELSE IF m$ = ">" THEN c% = c% + VAL(o$)
      IF m$ <> "=" THEN o$ = RIGHT$(o$, LEN(o$) - LEN(LTRIM$(STR$(VAL(o$)))))
      res$ = res$ + CHR$(c%)
   WEND
   decript$ = res$
END FUNCTION

FUNCTION encript$ (a$)
   a% = ASC(LEFT$(a$, 1)): out$ = LTRIM$(STR$(a%))
   FOR i% = 2 TO LEN(a$)
      m% = ASC(MID$(a$, i%, 1))
      IF m% = a% THEN
         out$ = out$ + "="
      ELSEIF m% < a% THEN
         out$ = out$ + "<" + LTRIM$(STR$(a% - m%))
      ELSE
         out$ = out$ + ">" + LTRIM$(STR$(m% - a%))
      END IF
      a% = m%
   NEXT i%
   encript$ = out$
END FUNCTION

I've invented another encryptation algo. The output was:

Code:

35520781707917087370403237390843093082270089242032262084180723599073160833251033

Now crack this one.