another date challenge

[Antoni Gual]

Small is beautiful

Code:

'Conversion of day of year and year to day of month and day of week
'by Antoni gual 2006/12/15 for Agamemnus contest at QBN
'Tested in QB 1.1
'
DEFINT A-Z
DECLARE FUNCTION DayofWeek (y, m, D)
DECLARE FUNCTION ISLEAPYEAR (y)
DECLARE FUNCTION daysinmonth (y, m)

DO
INPUT "year (0 to exit)"; y
IF y < 1 THEN EXIT DO
INPUT "day of year"; dy
IF dy < 1 OR dy > 365 - ISLEAPYEAR(y) THEN PRINT "bad day of year": END
nt = 0
m = 0
DO
n = nt
m = m + 1
nt = nt + daysinmonth(y, m)
LOOP UNTIL dy <= nt

dm = dy - n
'PRINT "month (1=January...12=December)"; m
PRINT "day of month = "; dm
PRINT "day of week (1=monday...7=sunday) "; DayofWeek(y, m, dm) + 1
LOOP
END
'
'-------------------------------------------------------------------------
FUNCTION DayofWeek (y, m, D)
  '0=monday
  DIM P, Q
  IF m > 2 THEN
    P = m - 3
    Q = y
  ELSE
    P = m + 9
    Q = y - 1
  END IF
DayofWeek = (D + 1 + Q + Q \ 4 - Q \ 100 + Q \ 400 + CINT(2.6 * P)) MOD 7
END FUNCTION

'
'-------------------------------------------------------------------------
FUNCTION daysinmonth (y, m)
'get nr of days in a month  of a year(check for leap year if february)
SELECT CASE m
CASE 2: daysinmonth = 28 - ISLEAPYEAR(y)
CASE 1, 3, 5, 7, 8, 10, 12: daysinmonth = 31
CASE ELSE: daysinmonth = 30
END SELECT
END FUNCTION

'
'-------------------------------------------------------------------------
FUNCTION ISLEAPYEAR (y)
'Returns -1 if Gregorian year y is a leap year
ISLEAPYEAR = (y MOD 4 = 0) - (y MOD 100 = 0) + (y MOD 400 = 0)
END FUNCTION
'
'--------------------------------------------------------------------------